symbol tank_reading = w0
symbol cell_reading = w1

symbol tank_level = w2
symbol cell_mV = w3

symbol sensor_circuit_pin = 7
symbol tank_sensor_pin = 1
symbol tank_cell_pin = 0

symbol tank_min_reading = 204
symbol tank_max_reading = 610

symbol sleep_period = 52 '~120 seconds
 
main:

	'turn on sensor, transmitter
	low sensor_circuit_pin
	
	'pause to allow things to power up
	pause 5
	
	'read and transmit data
	gosub transmit
	
	'turn off sensor, transmitter
	high sensor_circuit_pin 
	
	'sleep until next time
	sleep sleep_period

	goto main

transmit:
	'read tank sensor
	readadc10 tank_sensor_pin,tank_reading

	if tank_reading < tank_min_reading then
		tank_level = 0
	elseif tank_reading > tank_max_reading then
		tank_level = 100
	else
		tank_reading = tank_reading - tank_min_reading
		tank_reading = tank_reading * 100
		tank_level = tank_reading / 410
	endif

	'read AA cell
	readadc tank_cell_pin,cell_reading
	
	cell_reading = 25600 / cell_reading '256 (8 bit adc resolution) * 100 
	cell_mV = 50000 / cell_reading '500 (mV of Vcc) * 100

	'transmit data
	serout 3,N2400,(85,85,85,85,"ABC",tank_level,cell_mV)
	
	sertxd("transmitted: ",#tank_level,":",#cell_mV,cr,lf)
	
	return